ANSYS APDL 應用技巧

2017-07-07 by:CAE仿真在線來源:互聯(lián)網(wǎng)

1. 前言

APDL的全稱是ANSYS Parametric Design Language(ANSYS參數(shù)化設(shè)計語言),是一種解釋型語言,具有變量定義、判斷、循環(huán)、文件讀寫等功能。

用戶可以利用APDL編寫出參數(shù)化的用戶程序,從而實現(xiàn)有限元分析的全過程,即建立參數(shù)化的CAD模型、參數(shù)化的網(wǎng)格劃分與控制、參數(shù)化的材料定義、參數(shù)化的載荷和邊界條件定義、參數(shù)化的分析控制和求解以及參數(shù)化的后處理。

學會使用APDL是成為ANSYS高級用戶的重要標志。本文將介紹筆者過去幾年實際工作中的一些APDL應用經(jīng)驗,歡迎廣大同行指點、交流。

2. 工具

ANSYS的APDL編寫完后通常保存為后綴為.txt或.inp的文本文件,從微軟自帶的記事本到Notepad++,PSPAD,UltraEdit等專業(yè)開發(fā)程序都可作為編輯工具。筆者最初是用Notepad++作為APDL的編寫工具,將背景設(shè)置成護眼色,使用起來也頗滿意。偶然一次,看到部門里一位澳大利亞留學回來的IT工程師同事在用Sublime開發(fā)Python代碼,一下子就被Monokai主題配色深深地吸引住了。從此,筆者投向了Sublime的懷抱,其工作界面如下圖。

ANSYS APDL 應用技巧ansys分析圖片1

需要說明的是,Sublime安裝完后,需要再安裝APDL-Syntax-master插件(可從GITHUB下載),才可以支持ANSYS APDL語法高亮。

另外,編寫APDL命令流時,可打開ANSYS官方的 Element Reference 和 Command Reference 兩個pdf文件作為工具書供隨時查閱參考。

3. 前處理

ANSYS的前處理體驗相對HyperMesh/ANSA等專業(yè)前處理軟件來說,相差得不是一點點。主要體現(xiàn)在以下兩個方面:

1.3D幾何模型特征簡化、拓撲修復結(jié)構(gòu)分析的幾何模型通常由設(shè)計部門提供,往往存在大量的倒角、圓角、安裝定位孔、注塑澆口甚至破面等缺陷,面對這樣的幾何模型,ANSYS處理起來是相當吃力甚至無法處理。

2.布爾運算網(wǎng)格劃分前,通常需要對體、面進行剖分以獲得較為規(guī)則的網(wǎng)格。ANSYS的布爾操作常常不是失敗,就是生成了一些碎細的線、面、體,需要更多的時間來處理修復。

Workbench的出現(xiàn),在很大程度上提升了ANSYS的前處理能力,HyperMesh等專業(yè)前處理軟件也可以導出ANSYS的cdb文件。因此,對于工程中較為復雜的模型,可運用APDL讀入cdb模型,然后在命令流文件中定義材料參數(shù)、接觸參數(shù)、約束、載荷等,最終提交給程序求解。

對于較為簡單、規(guī)則的模型,可直接利用APDL參數(shù)化建模,方便幾何尺寸、材料屬性、載荷、約束等參數(shù)的影響分析。尤其對于多層薄膜復合材料問題(比如十多層),在APDL中可方便修改疊層設(shè)計(各鋪層厚度)、各鋪層材料屬性/鋪角等,大大提高建模、研究效率。

示例如下:

/prep7

! ---------------------------------------

! parameters defination

! ---------------------------------------

*set, all, , ! clear all parameters

R1 = 5.0 ! radius of thin film

T1 = 5.0e-3 ! thickness of thin film

P1 = 1.0 ! pressure

ESZ = 0.2 ! global element size

! ---------------------------------------

! element and material property

! ---------------------------------------

et, 1, shell181

keyopt, 1, 1, 0 ! bending and membrane stiffness (default)

keyopt, 1, 8, 0 ! store data for botoom of bottom layer and top of top layer (default)

sectype, 1, shell

secdata, T1, 1, 0.0, 3

secoffset, MID

mp, ex, 1, 190e6 ! Si

mp, dens, 1, 2.33e-6

mp, nuxy, 1, 0.278

! ---------------------------------------

! thin film geometry modeling and meshing

! ---------------------------------------

csys, 0

mat, 1

type, 1

real, 1

cyl4, 0, 0, 0, 0, R1, 360

wprota, , 90

asbw, all

wprota, , , 90

asbw, all

asel, all

aatt, 1, 1, 1 ! mat, real, type

mshape, 0, 2D

allsel

lesize, all, ESZ

amesh, all

csys, 1

nsel, s, loc, x, R1

d, all, all, 0

! secplot, 1 ! plot the geometry of a shell section

! /eshape, 1 ! displays elements with shapes determined from the section definition

csys, 0

allsel

save

finish

4. 求解

利用APDL可方便的設(shè)置分析類型、重啟動、求解器、輸出內(nèi)容、載荷、單元生死、非線性控制等。

示例如下:

! ---------------------------------------

! solve

! ---------------------------------------

/solu

antype, static ! perform a static analysis

nropt, full ! use full newton-raphson

outpr, all, none

outres, basic, all ! write the solution for every substep

sfa, all, 1, pres, P1

! sf, all, pres, P1

solcontrol, on ! used optimizied nonlinear solution defaults

nlgeom, on ! includes large-deflection effects

kbc, 0 ! ramped loading

nsubst, 45, 60, 30 ! specifles the number of substeps to be taken in this load step

time, 1 ! sets the time for a load step

allsel

solve

finish

注意,當APDL命令流較長時,直接復制粘貼在命令流輸入框會花費較長時間。推薦的快速讀入方法是,將APDL命令流保存為文本文件(.txt或.inp后綴),然后在GUI中通過File > Read Input from提交,或在ANSYS Mechanical APDL Product Launcher通過ANSYS Batch提交,如下圖。

ANSYS APDL 應用技巧ansys分析圖片2

5. 后處理

利用APDL可以方便地從結(jié)果文件中提取模態(tài)頻率、諧響應、接觸力、節(jié)點位移/溫度/電壓等數(shù)據(jù),并按一定格式寫出(FORTRAN輸入輸出格式控制),可將寫出的數(shù)據(jù)用MATLAB/Python讀入進行數(shù)據(jù)處理、繪圖。用較少的代碼,即可省去在量的重復操作,大大提高工作效率。

示例如下:

*cfopen, , ndisp

*vwrite,

(' i_SET LoadStep N_UX N_UY N_UZ')

*vwrite, NodeDisp(1,1), NodeDisp(1,2), NodeDisp(1,3), NodeDisp(1,4), NodeDisp(1,5)

(F6.0, 4x, F4.0, 2x, E20.10, 2x, E20.10, 2x, E20.10)

*cfc

ANSYS APDL 應用技巧ansys workbanch圖片3