搜索彈塑性專題-三桿對稱桁架理想彈塑性ANSYS分析
2017-03-05 by:CAE仿真在線 來源:互聯(lián)網(wǎng)
導讀:理想彈塑性材料模型用雙線性隨動強化模型。彈性極限載荷、塑性極限載荷和卸載,按照載荷步,依此施加載荷,設置載荷子步和自動時間步長,求解。后處理的豎直位移變形在直角坐標系下參看,應力和應變在單元坐標系下查看。
一、問題描述
有一個三桿桁架,受豎直向下的載荷F作用,豎桿長度L=100 mm,橫截面積A=10 mm2,彈性模量E=200 GPa,泊松比為0.3,角度為45°,屈服強度為250 MPa。在彈性極限載荷、塑性極限載荷和卸載后的條件下,計算豎直位移、各桿應力和應變。例子來源于塑性力學教材。
問題分析
桁架用LINK180桿單元,理想彈塑性材料模型用雙線性隨動強化模型。彈性極限載荷、塑性極限載荷和卸載,按照載荷步,依此施加載荷,設置載荷子步和自動時間步長,求解。后處理的豎直位移變形在直角坐標系下參看,應力和應變在單元坐標系下查看。
計算結果
根據(jù)解析公式,表中彈性極限載荷Fe= 4267.8N,塑性極限載荷Fp= 6035.5N。
表中藍色字體與解析解完全吻合,驗證了ANSYS的計算結果是正確的。
對于理想彈塑性模型,塑性應變不承載,應力為彈性模量乘以彈性應變。
總應變等于彈性應變加上塑性應變。
卸載后,桿①和桿③是彈性應變3.66E-04;桿②既有彈性應變-5.18E-04,也有塑性應變1.25E-03,彈性應變加上塑性應變等于總應變7.32E-04。
1.結果匯總
2.云圖結果
(1)卸載后殘余變形云圖
(2)應力云圖
(a)彈性極限載荷作用下的應力云圖,中間桿先屈服
(b)塑性極限載荷作用下的應力云圖,所有桿都屈服
(c)卸載后的殘余應力云圖
(3)卸載后的各種應變
(a)卸載后的彈性應變云圖
(b)卸載后的塑性應變云圖
(c)卸載后的總應變云圖
二、理論計算
參考文獻:王春玲. 塑性力學 [M]. 北京: 中國建材工業(yè)出版社, 2005:6-10
三、GUI步驟
1.進入ANSYS
程序→ANSYS→ANSYS Product Launcher→改變working directory到指定文件夾→在job name輸入:Link→Run。job name可默認為file。
2.定義單元屬性
(1)定義單元類型:MainMenu >Preprocessor >Element Type >Add/Edit/Delete →Add →在左列表框中選擇Link,在右列表框中選擇3D finit stn 180 →OK →Close。
(2)定義實常數(shù):MainMenu >Preprocessor >Real Constants >Add →Type 1 →OK →Real Constant→ Set→ No.:1;AREA:10→OK →Close。
(3)設置材料屬性:
①彈性模量和泊松比:MainMenu >Preprocessor >Material Props >Material Models →Structural →Linear → Elastic →Isotropic →EX:2E5;PRXY:0.3→OK。
②理想彈塑性模型:Main Menu>Preprocessor >Material Props >Material Models →Structural →Nonlinear → 見下圖 →雙擊Bilinear(雙線性)→Yield Stress:250;Tang Mods:0 →OK。關鍵步驟!雙線性隨動強化(BKIN)可定義理想彈塑性模型。
3.建立模型
(1)定義節(jié)點:MainMenu >Preprocessor >Create >Nodes > In Active CS →依次輸入4個節(jié)點坐標1(-100,0,0),2(0,0,0),3(100,0,0),4(0,-100,0)→OK。
(2)定義單元:
①定義單元:MainMenu >Preprocessor >Create >Elements >Auto Numbered >Thru Nodes→拾取節(jié)點1和4→Apply →拾取節(jié)點2和4→Apply →拾取節(jié)點3和4→OK。
②打開桿單元的單元形狀:UtilityMenu>PlotCtrls>Style>Size and Shape →[/ESHAPE]: On。
4.施加位移約束
(1)施加位移約束MainMenu > Solution > Define loads > Apply > Structural >Displacement > On Nodes →拾取節(jié)點1、2和3→OK →Lab2:All DOF →OK。
(2)保存模型:UtilityMenu >Files >Save as →輸入Link_model.db→OK。
5.非線性求解設置
MainMenu>Solution>Analysis Type>Sol'n Controls→Automatic time stepping(自動時間步長):ON;Number ofsubsteps(載荷子步):10;Frequency(寫出結果頻率):Writelast substep only→OK。
6.按照載荷步依次求解
(1)第1載荷步
①施加載荷:MainMenu > Solution > Define loads > Apply > Structural >Force/Moment > On Nodes →拾取節(jié)點4→OK →Lab:FY;VALUE:-2133.9→OK。
②求解:MainMenu > Solution >Solve >Current LS →File >Close →Solve Current LoadStep →OK →Solution is done →Close。
(2)第2載荷步~第8載荷步
重復第(1)步,改變對應的載荷大小,求解。每個載荷步施加的載荷大小見下表。
(3)保存結果文件:UtilityMenu >Files >Save as →輸入Link_Solve.db→OK。
7.后處理
(1)讀入載荷步的結果:MainMenu >General Postproc >Read Results >By Pick →拾取想要看的載荷步→Read →Close。
(2)豎直位移云圖:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu →DOFsolution→Y-component of displacement (Y方向的位移)→OK。位移結果默認是在整體直角坐標系下。
(3)軸向應力云圖:MainMenu>General Postproc>Plot Results >Contour Plot >Nodal Solu →Stress→X-component of stress (軸向應力)→OK。軸向應力結果是在單元坐標系下顯示,軸向為單元坐標系的X方向。
(4)彈性應變云圖:MainMenu>General Postproc>Plot Results>Contour Plot>Nodal Solu →Elastic Strain→X-component of elastic strain(彈性應變)→OK。也是在單元坐標系下顯示。
(5)塑性應變云圖:MainMenu>General Postproc>Plot Results>Contour Plot>Nodal Solu →Plastic Strain→X-component of plastic strain(塑性應變)→OK。也是在單元坐標系下顯示。
(6)總應變云圖:MainMenu>General Postproc>Plot Results>Contour Plot>Nodal Solu → Total Mechanical Strain→X-component of total mechanical strain(總應變)→OK。也是在單元坐標系下顯示。
四、APDL步驟
/PREP7
ET,1,LINK180 !單元類型
R,1,10 !實常數(shù)
MP,EX,1,2e5
TB,BKIN !雙線性隨動強化(BKIN)可定義理想彈塑性
TBTEMP,0
TBDATA,1,250 !屈服應力
N,1,-100,0,0 !節(jié)點
N,2,0,0,0
N,3,100,0,0
N,4,0,-100,0
E,1,4 !單元
E,2,4
E,3,4
D,1,ALL !約束
D,2,ALL
D,3,ALL
FINISH
/SOLU
AUTOTS,ON !自動載荷步
NSUBST,10 !載荷子步
OUTRES,ALL,LAST !輸出最后子步
F,4,FY,-2133.9 !加載
SOLVE !第1載荷步求解
F,4,FY,-4267.8 !加載:彈性極限載荷
SOLVE !第2載荷步求解
F,4,FY,-5151.7
SOLVE !第3載荷步求解
F,4,FY,-6035.5 !加載:塑性極限加載
SOLVE !第4載荷步求解
F,4,FY,-5151.7 !卸載
SOLVE !第5載荷步求解
F,4,FY,-4267.8 !卸載到施加的彈性極限載荷
SOLVE !第6載荷步求解
F,4,FY,-2133.9
SOLVE !第7載荷步求解
F,4,FY,0 !全卸載
SOLVE !第8載荷步求解
FINISH
/POST1
SET,,,,,,,2 !拾取想要看的載荷步
PLNSOL, S,X, 0,1.0 !應力云圖
PLNSOL, EPEL,X, 0,1.0 !彈性應變云圖
PLNSOL, EPPL,X, 0,1.0 !塑性應變云圖
PLNSOL, EPTO,X, 0,1.0 !總應變云圖
相關標簽搜索：彈塑性專題-三桿對稱桁架理想彈塑性ANSYS分析 Ansys有限元培訓 Ansys workbench培訓 ansys視頻教程 ansys workbench教程 ansys APDL經典教程 ansys資料下載 ansys技術咨詢 ansys基礎知識 ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓
