搜索在ansys中導(dǎo)入自定義本構(gòu)模型的算例
2016-10-24 by:CAE仿真在線(xiàn) 來(lái)源:互聯(lián)網(wǎng)
模型的關(guān)鍵點(diǎn)是材料的彈性模量隨大小主應(yīng)力差及小主應(yīng)力(圍壓)的變化而變化,用APDL實(shí)現(xiàn)之的基本思路是:給每個(gè)單元定義一個(gè)材料號(hào),分級(jí)施加荷載,在每個(gè)荷載步結(jié)束時(shí)提取出各單元的大小主應(yīng)力,據(jù)此計(jì)算出下個(gè)荷載步的彈性模量Et,修改各單元之MP,用于下一步計(jì)算。
以下是一個(gè)簡(jiǎn)單算例,copy出去可直接運(yùn)行。
!!!常規(guī)三軸試驗(yàn)?zāi)M
!!!by taomingxing,NWPU
!!!2003.7.16
FINISH
/CLEAR
/TITLE,Numerical Simulation of three axes testing of soils
/PREP7
*dim,SUy,array,50 !Settlement records
*dim,MaxPs,array,120 !Max history p1-p3
*dim,MaxDs,array,120 !Max history Ds
!*dim,EEt,array,50 !Et of elememt
!!!Duncan-Chang Model
!!!Symbols:c-粘滯力,Fai-內(nèi)摩擦角,Sf-破壞強(qiáng)度(p1-p3)f,Ds-應(yīng)力水平,Pa-大氣壓,P3-圍壓
*CREATE,Duncan-Chang !Creat Macro file
*afun,deg !Unit of angle
*set,Pa,1e5
*set,P1,-ArrS3(i) !注意:巖土工程中應(yīng)力為拉負(fù)壓正
*set,P3,-ArrS1(i)
*if,P3,LT,0.1*Pa,then
P3=0.1*Pa !圍壓最小取值
*endif
Sf=2*(c*cos(Fai)+P3*sin(Fai))/(1-sin(Fai)) !Mohr-Coulomb破壞強(qiáng)度(p1-p3)f
Ds=(P1-P3)/Sf !應(yīng)力水平,
*if,Ds,GT,0.95,then
Ds=0.95 !應(yīng)力水平最大取值
*endif
!判斷加卸荷,如果(P1-P3)小于歷史最大值視為卸荷-再加荷過(guò)程
*if,MaxPs(i),LT,P1-P3,then
Ei=k*Pa*(P3/Pa)**n
Et=Ei*(1-Rf*Ds)**2 !加荷情況的切線(xiàn)模量
MaxPs(i)=P1-P3 !保存歷史最大應(yīng)力
*elseif,MaxPs(i),GE,P1-P3
Et=Kur*Pa*(P3/Pa)**n !卸荷模量
*endif
mp,ex,i,Et !修改單元i的Et
mp,nuxy,i,Mu
*END
!!!單元類(lèi)型
et,1,42 !平面四節(jié)點(diǎn)單元
KEYOPT,1,3,2 !平面應(yīng)變
!!!以下定義材料初始模量
mp,ex,1,3.728e7 !砂土的彈性模量
mp,nuxy,1,0.33
mp,dens,1,1800
!!!建立幾何模型
blc4,0,0,0.08,0.15 !8cm X 15cm
/PNUM,AREA,1
/REPLOT
!!!網(wǎng)格劃分
aesize,all,0.01
mat,1
amesh,all
!!!邊界條件
nsel,s,loc,y,0
d,all,Uy !底邊界豎向約束
nsel,s,loc,x,0
d,all,Ux !左側(cè)邊界水平向約束
nsel,all
/replot
fini
/SOLU
time,0.01 !施加圍壓
sfl,all,pres,2e5 !200kPa
solve
!!!分級(jí)施加荷載,實(shí)現(xiàn)非線(xiàn)性計(jì)算
!!!荷載增量10kPa,共50級(jí)
*DO,ti,1,50
!!!取出計(jì)算結(jié)果,修改彈性模量
/POST1
*get,SUy(ti),node,29,u,y !Settlement record of time ti
ETABLE,EtabS1,S,1 !取各單元第一主應(yīng)力
ETABLE,EtabS3,S,3 !取各單元第三主應(yīng)力
*dim,ArrS1,array,120
*dim,ArrS3,array,120
*do,Num,1,120 !Num為單元編號(hào)
*get,ArrS1(Num),elem,Num,etab,EtabS1 !將單元結(jié)果存入數(shù)組
*get,ArrS3(Num),elem,Num,etab,EtabS3
*enddo
/PREP7
!^^修改砂土單元的Et,單元號(hào)1-120
c=0 $Fai=35 $Rf=0.7 $k=400 $n=0.6 $Mu=0.33 $Kur=326.7
*do,i,1,120 !各單元循環(huán)計(jì)算
*use,Duncan-Chang,c,Fai,Rf,k,n,Mu,Kur !調(diào)用Duncan-Chang宏文件
*enddo
!EEt(ti)=ET !保存第120單元之ET
/SOLU
time,ti
sfl,3,pres,2e5+1e4*ti !施加荷載,增量1e4
solve !對(duì)ti級(jí)荷載情況求解
*ENDDO
相關(guān)標(biāo)簽搜索：在ansys中導(dǎo)入自定義本構(gòu)模型的算例 Ansys有限元培訓(xùn) Ansys workbench培訓(xùn) ansys視頻教程 ansys workbench教程 ansys APDL經(jīng)典教程 ansys資料下載 ansys技術(shù)咨詢(xún) ansys基礎(chǔ)知識(shí) ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓(xùn)
